usm/src/lib/meson.build

add_project_arguments(['--debug', '--disable-warnings', '--enable-checking','--vapidir', vapi_dir], language: 'vala')

sources = files('Manifest.vala')
sources += files('Dependencies.vala')
sources += files('Exectuables.vala')
sources += files('File.vala')
sources += files('Git.vala')
sources += files('Licence.vala')
sources += files('Paths.vala')
sources += files('ResourceRef.vala')
sources += files('Version.vala')
sources += files('Resolver.vala')
sources += files('Util.vala')
sources += files('Transaction.vala')
sources += files('Repository/Repository.vala')
sources += files('Repository/RepositoryListing.vala')
sources += files('Repository/RepositoryClient.vala')
sources += files('Repository/GioRepositoryClient.vala')
sources += files('State/State.vala')
sources += files('State/CachedPackage.vala')
sources += files('State/OriginInformation.vala')


dependencies = [
    dependency('glib-2.0'),
    dependency('gobject-2.0'),
    dependency('gio-2.0'),
    dependency('gee-0.8'),
    dependency('json-glib-1.0'),
    dependency('invercargill'),
    dependency('invercargill-json'),
    dependency('libarchive'),
    meson.get_compiler('vala').find_library('libsodium', dirs: vapi_dir),
    meson.get_compiler('c').find_library('sodium'),
]

usm = shared_library('usm', sources,
    dependencies: dependencies,
    install: true,
    vala_gir: 'usm-1.0.gir',
    install_dir: [true, true, true, true]
)
usm_dep = declare_dependency(link_with: usm, include_directories: include_directories('.'))

pkg = import('pkgconfig')
pkg.generate(usm,
    version : '0.1',
    name : 'usm',)
    
g_ir_compiler = find_program('g-ir-compiler')
custom_target('usm typelib', command: [g_ir_compiler, '--shared-library=libusm.so', '--output', '@OUTPUT@', meson.current_build_dir() / 'usm-1.0.gir'],
              output: 'usm-1.0.typelib',
              depends: usm,
              install: true,
              install_dir: get_option('libdir') / 'girepository-1.0')