libppub/src/lib/meson.build

dependencies = [
    dependency('glib-2.0'),
    dependency('gobject-2.0'),
    dependency('gio-2.0'),
    dependency('gee-0.8'),
    dependency('invercargill'),
    meson.get_compiler('vala').find_library('libsodium', dirs: vapi_dir),
    meson.get_compiler('c').find_library('sodium'),
]

sources = files('Ppub.vala')
sources += files('Asset.vala')
sources += files('Metadata.vala')
sources += files('AssetStream.vala')
sources += files('Builder.vala')
sources += files('StreamMonitor.vala')
sources += files('Ppvm.vala')
sources += files('Ppix.vala')
sources += files('Ppcl.vala')

ppub = shared_library('libppub', sources,
    name_prefix: '',
    dependencies: dependencies,
    install: true,
    vala_gir: 'Ppub-1.0.gir',
    install_dir: [true, true, true, true]
)
ppub_dep = declare_dependency(link_with: ppub, include_directories: include_directories('.'))

pkg = import('pkgconfig')
pkg.generate(ppub,
    version : '0.1',
    name : 'libppub',)
    
g_ir_compiler = find_program('g-ir-compiler')
custom_target('ppub typelib', command: [g_ir_compiler, '--shared-library=libppub.so', '--output', '@OUTPUT@', meson.current_build_dir() / 'Ppub-1.0.gir'],
              output: 'Ppub-1.0.typelib',
              depends: ppub,
              install: true,
              install_dir: get_option('libdir') / 'girepository-1.0')