Statum/meson.build

project('statum', ['c', 'vala'],
  version: '0.1',
)

vapi_dir = join_paths(meson.current_source_dir(), 'vapi')

# Dependencies
glib_dep = dependency('glib-2.0')
gobject_dep = dependency('gobject-2.0')
gio_dep = dependency('gio-2.0')
gee_dep = dependency('gee-0.8')
invercargill_dep = dependency('invercargill-1')
inversion_dep = dependency('inversion-0.1')
astralis_dep = dependency('astralis-0.1')
json_glib_dep = dependency('json-glib-1.0')
libxml_dep = dependency('libxml-2.0')
invercargill_json_dep = dependency('invercargill-json')
invercargill_sql_dep = dependency('invercargill-sql', required: true)
invercargill_sql_inversion_dep = dependency('invercargill-sql-inversion', required: true)
sqlite_dep = dependency('sqlite3')

# libsodium is consumed via a bundled VAPI (libsodium does not ship one).
sodium_vapi = files('vapi/libsodium.vapi')
sodium_c_lib = meson.get_compiler('c').find_library('sodium', required: true)
sodium_deps = declare_dependency(sources: sodium_vapi, dependencies: sodium_c_lib)

# VAPI Directory
add_project_arguments(['--vapidir', vapi_dir], language: 'vala')

# Tools are built first (from source — never required to be installed) so the
# library can use them at its own build time (e.g. to embed the client scripts).
subdir('tools')
subdir('src')
subdir('example')