Statum/example/meson.build

# Statum end-to-end example app.
#
# A small but complete browser-driven Statum application: a server-rendered,
# client-hydrated home page with login/logout actions. The Statum client
# scripts are embedded in libstatum and served by default, so this only
# generates the page (home.html + main.html template) and the page CSS.

home_page = custom_target('home-page',
    input: 'home.html',
    output: 'HomePage.vala',
    command: [statum_mkpstm, '-o', '@OUTPUT@', '-n', 'HomePage', '--ns=Example', '@INPUT@'],
    depend_files: files('main.html', 'counter-card.html')
)

dashboard_page = custom_target('dashboard-page',
    input: 'dashboard.html',
    output: 'DashboardPage.vala',
    command: [statum_mkpstm, '-o', '@OUTPUT@', '-n', 'DashboardPage', '--ns=Example', '@INPUT@'],
    depend_files: files('main.html')
)

styles_resource = custom_target('styles-resource',
    input: 'styles.css',
    output: 'StylesResource.vala',
    command: [statum_mkres, '-o', '@OUTPUT@', '-n', 'styles.css', '-c', 'text/css', '@INPUT@']
)

executable('statum-example',
    ['Main.vala', 'HomeEntrypoint.vala', 'Actions.vala', home_page, dashboard_page, styles_resource],
    dependencies: [statum_dep],
    install: false
)