sources = files(
    'Spry.vala',
    'ResponseState.vala',
    'Component.vala',
    'PageComponent.vala',
    'PageTemplate.vala',
    'ComponentFactory.vala',
    'Renderable.vala',
    'ComponentEndpoint.vala',
    'Context.vala',
    'PathProvider.vala',
    'ContinuationProvider.vala',
    'ContinuationContext.vala',
    'CryptographyProvider.vala',
    'Static/StaticResource.vala',
    'Static/MemoryStaticResource.vala',
    'Static/FileStaticResource.vala',
    'Static/ConstantStaticResource.vala',
    'Static/StaticResourceProvider.vala',
    'Static/HtmxResource.vala',
    'Static/HtmxSseResource.vala'
)


library_version = meson.project_version()
libspry = shared_library('spry-@0@'.format(library_version),
    sources,
    dependencies: [glib_dep, gobject_dep, gio_dep, invercargill_dep, invercargill_json_dep, json_glib_dep, inversion_dep, libxml_dep, astralis_dep, sodium_deps],
    install: true,
    vala_gir: 'spry-@0@.gir'.format(library_version),
    install_dir: [true, true, true, true]
)


pkg = import('pkgconfig')
pkg.generate(libspry,
    version : library_version,
    name : 'spry-@0@'.format(library_version))
    
g_ir_compiler = find_program('g-ir-compiler')
custom_target('spry typelib', command: [g_ir_compiler, '--shared-library=libspry-@0@.so'.format(library_version), '--output', '@OUTPUT@', meson.current_build_dir() / 'spry-@0@.gir'.format(library_version)],
              output: 'libspry-@0@.typelib'.format(library_version),
              depends: libspry,
              install: true,
              install_dir: get_option('libdir') / 'girepository-1.0')


spry_dep = declare_dependency(
    link_with: libspry,
    include_directories: include_directories('.'),
    dependencies: [glib_dep, gobject_dep, gio_dep, invercargill_dep, invercargill_json_dep, json_glib_dep, inversion_dep, libxml_dep]
)

# Authorisation submodule
subdir('Authorisation')