Invercargill/src/lib/Modifiers/Concat.vala

namespace Invercargill.Modifiers {

    public class Concat<T> : Enumerable<T> {

        private Enumerable<T> e1;
        private Enumerable<T> e2;

        public Concat(Enumerable<T> first, Enumerable<T> second) {
            e1 = first;
            e2 = second;
        }

        public override int? peek_count() {
            var c1 = e1.peek_count();
            var c2 = e2.peek_count();
            if(c1 == null || c2 == null)
                return null;
            return c1 + c2;
        }

        public override EnumerableInfo get_info() {
            return new EnumerableInfo.infer(this, EnumerableCategory.COMPUTED, Iterate.these(e1, e2));
        }

        public override Tracker<T> get_tracker() {
            var tracker1 = e1.get_tracker();
            var tracker2 = e2.get_tracker();

            return new LambdaTracker<T>(
                () => tracker1.has_next() || tracker2.has_next(),
                () => {
                    if(tracker1.has_next()) {
                        return tracker1.get_next();
                    }
                    return tracker2.get_next();
                });
        }

    }

}