123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482 |
- using Invercargill.DataStructures;
- using Invercargill.Modifiers;
- using Invercargill.Mapping;
- namespace Invercargill {
- public abstract class Enumerable<T> : Object {
- public abstract Tracker<T> get_tracker();
- // Returns false if iteration was interrupted
- // Returns true if iteration reached natural end
- public virtual bool iterate_if(PredicateDelegate<T> handler) {
- var tracker = get_tracker();
- while(tracker.has_next()) {
- if(!handler(tracker.get_next())) {
- return false;
- }
- }
- return true;
- }
- public virtual void iterate(ItemDelegate<T> handler) {
- iterate_if(i => {
- handler(i);
- return true;
- });
- }
- public virtual Series<T> to_series() {
- var series = new Series<T>();
- iterate(i => series.add(i));
- return series;
- }
- public virtual Gee.Collection<T> to_gee_collection() {
- var collection = new Gee.LinkedList<T>();
- iterate(i => collection.add(i));
- return collection;
- }
- public virtual Tracker<T> iterator() {
- return get_tracker();
- }
- public virtual T[] to_array() {
- var array = new T[1024];
- var index = 0;
- foreach (var item in this) {
- if(index >= array.length) {
- array.resize(array.length*2);
- }
- safely_assign_to_array<T>(array, index, item);
- index++;
- }
- array.resize(index);
- return array;
- }
- public virtual int count() {
- var count = 0;
- iterate(i => count++);
- return count;
- }
- public virtual bool any(PredicateDelegate<T>? predicate = null) {
- var result = false;
- var p = resolve_nullable_predicate(predicate);
- iterate_if(i => {
- if(p(i)) {
- result = true;
- return false;
- }
- return true;
- });
- return result;
- }
- public virtual bool all(PredicateDelegate<T> predicate) {
- return !any(i => !predicate(i));
- }
- public virtual bool no(PredicateDelegate<T>? predicate = null) {
- var p = resolve_nullable_predicate(predicate);
- return all(i => !p(i));
- }
- public virtual Enumerable<T> where(owned PredicateDelegate<T> predicate) {
- return new Filter<T>(this, (owned)predicate);
- }
- public virtual Enumerable<T> from(owned PredicateDelegate<T> predicate) {
- return new From<T>(this, (owned)predicate);
- }
- public virtual Enumerable<T> until(owned PredicateDelegate<T> predicate) {
- return new Until<T>(this, (owned)predicate);
- }
- public virtual Enumerable<Tout> select_where<Tout>(owned FilterTransformDelegate<T, Tout> transform) {
- return new FilterTransform<T, Tout>(this, (owned)transform);
- }
- public virtual Enumerable<Tout> select<Tout>(owned TransformDelegate<T, Tout> transform) {
- return new Transform<T, Tout>(this, (owned)transform);
- }
- public virtual Attempts<Tout> attempt_select<Tout>(owned AttemptTransformDelegate<T, Tout> transform) {
- return select<Attempt<Tout>>(i => new Attempt<Tout>(() => transform(i))).assert_promotion<Attempts>();
- }
- public virtual Attempts<Tout> attempt_select_nested<Tout>(owned AttemptTransformDelegate<T, Enumerable<Attempt<Tout>>> transform) {
- return attempt_select<Enumerable<Attempt<Tout>>>((owned)transform)
- .as_enumerable()
- .select_many<Attempt<Tout>>(a => a.success ? a.result : Invercargill.single<Attempt<Tout>>(new Attempt<Tout>.unsuccessful(a.error)))
- .assert_promotion<Attempts>();
- }
- public virtual Enumerable<Pair<TFirst, TSecond>> select_pairs<TFirst, TSecond>(owned TransformDelegate<T, TFirst> transform1, owned TransformDelegate<T, TSecond> transform2) {
- return select<Pair<TFirst, TSecond>>(i => new Pair<TFirst, TSecond>(transform1(i), true, transform2(i), true));
- }
- public virtual Enumerable<Tout> select_many<Tout>(owned TransformDelegate<T, Enumerable<Tout>> transform) {
- return new MergeQuery<Tout>(select((owned)transform));
- }
- public virtual Enumerable<T> sort(owned CompareDelegate<T> compare) {
- return new Sort<T>(this, (owned)compare);
- }
- public virtual Enumerable<T> concat(Enumerable<T> other) {
- return new Concat<T>(this, other);
- }
- public virtual Enumerable<T> take(int count) {
- return new Take<T>(this, count);
- }
- public virtual Enumerable<T> skip(int count) {
- return new Skip<T>(this, count);
- }
- public virtual Enumerable<Tout> cast<Tout>() {
- return select<Tout>(i => (Tout)i);
- }
- // public virtual Enumerable<Tout> convert<Tout>() throws ConverterError {
- // var converter = get_converter<T, Tout>();
- // if(converter == null) {
- // throw new ConverterError.CONVERTER_NOT_FOUND(@"No converter registered that can convert from $(typeof(T).name()) to $(typeof(Tout).name())");
- // }
- // return select(((Converter<T, Tout>)converter).convert);
- // }
- public virtual Enumerable<Tout> parallel_select<Tout>(owned TransformDelegate<T, Tout> transform, uint workers = 0) {
- var actual_workers = workers;
- if(actual_workers < 1) {
- actual_workers = get_num_processors();
- }
- return new Parallel<T, Tout>(this, (owned)transform, (int)actual_workers);
- }
- public virtual int parallel_iterate(ItemDelegate<T> handler, uint workers = 0) {
- return parallel_select<T>(i => {
- handler(i);
- return i;
- }, workers)
- .count();
- }
- public virtual Enumerable<SelectionContext<T, Tout>> contextualised_select<Tout>(owned TransformDelegate<T, Tout> transform) {
- return select<SelectionContext<T, Tout>>((i) => new SelectionContext<T, Tout>() {
- origin = i,
- result = transform(i)
- });
- }
- public virtual Tout aggregate<Tout>(Tout initial, AggregateDelegate<Tout, T> aggregate_func) {
- var aggregate = initial;
- iterate(i => {
- aggregate = aggregate_func(aggregate, i);
- });
- return aggregate;
- }
- public virtual T max(TransformDelegate<T, int> int_delegate) {
- T item = null;
- var first = true;
- var value = 0;
- foreach (var i in this) {
- if(first) {
- first = false;
- item = i;
- value = int_delegate(i);
- continue;
- }
- var item_value = int_delegate(i);
- if(item_value > value) {
- value = item_value;
- item = i;
- }
- }
- return item;
- }
- public virtual T min(TransformDelegate<T, int> int_delegate) {
- T item = null;
- var first = true;
- var value = 0;
- foreach (var i in this) {
- if(first) {
- first = false;
- item = i;
- value = int_delegate(i);
- continue;
- }
- var item_value = int_delegate(i);
- if(item_value < value) {
- value = item_value;
- item = i;
- }
- }
- return item;
- }
- public virtual bool contains(T item, EqualityDelegate<T>? equator = null) {
- var func = equator ?? Operators.equality<T>();
- return any(i => func(i, item));
- }
- public virtual Enumerable<TOut> zip<TOther, TOut>(Enumerable<TOther> other, owned ZipperTransformDelegate<T, TOther, TOut> transform) {
- return new Zip<T, TOther, TOut>(this, other, (owned)transform);
- }
- public virtual Enumerable<Pair<T, Tother>> pair_up<Tother>(Enumerable<Tother> other) {
- return zip<Tother, Pair<T, Tother>>(other, (t1v, t1vs, t2v, t2vs) => new Pair<T, Tother>(t1v, t1vs, t2v, t2vs));
- }
- public virtual Enumerable<T> interleave(Enumerable<T> other) {
- return new Interleave<T>(this, other);
- }
- public virtual Enumerable<Tout> fork<Tout>(owned TransformDelegate<T, Tout> fork1, owned TransformDelegate<T, Tout> fork2) {
- var seq = to_series();
- return seq.select<Tout>((owned)fork1).interleave(seq.select<Tout>((owned)fork2));
- }
- public virtual Enumerable<Tout> fork_many<Tout>(owned TransformDelegate<T, Enumerable<Tout>> fork1, owned TransformDelegate<T, Enumerable<Tout>> fork2) {
- return new MergeQuery<Tout>(fork((owned)fork1, (owned)fork2));
- }
- public virtual bool matches(Enumerable<T> other, EqualityDelegate<T> equals) {
- return zip<T, bool>(other, (t1v, t1vs, t2v, t2vs) => t1vs == t2vs && equals(t1v, t2v)).all(r => r);
- }
- public virtual Enumerable<T> act(ItemDelegate<T> handler) {
- return select<T>(i => {
- handler(i);
- return i;
- });
- }
- public virtual Enumerable<T> distinct(owned EqualityDelegate<T>? comparison = null) {
- return distinct_by<T>(i => i, (owned)comparison);
- }
- public virtual Enumerable<T> distinct_by<TProp>(owned TransformDelegate<T, TProp> property_selector, owned EqualityDelegate<TProp>? property_equality) {
- var func = property_equality ?? Operators.equality<T>();
- return new Unique<T, TProp>(this, (owned)property_selector, (owned)func);
- }
- public virtual Enumerable<Grouping<TKey, T>> group_by<TKey>(owned TransformDelegate<T, TKey> key_selector, owned EqualityDelegate<TKey>? key_equality = null) {
- var equality = key_equality ?? Operators.equality<TKey>();
- var keys = select<TKey>(i => key_selector(i)).distinct((a, b) => equality(a, b));
- return keys.select<Grouping<TKey, T>>(g => new Grouping<TKey, T>(g, this.where(i => equality(g, key_selector(i)))));
- }
- public virtual Enumerable<T> @with(T item, uint times = 1) {
- return concat(range(0, (int)times, 1).select<T>(i => item));
- }
- public virtual T first(owned PredicateDelegate<T>? predicate = null) throws SequenceError {
- var tracker = predicate == null ? get_tracker() : where((owned)predicate).get_tracker();
- if(tracker.has_next()) {
- return tracker.get_next();
- }
- throw new SequenceError.NO_ELEMENTS("The sequence contains no elements");
- }
- public virtual T? first_or_default(owned PredicateDelegate<T>? predicate = null) {
- var tracker = predicate == null ? get_tracker() : where((owned)predicate).get_tracker();
- if(tracker.has_next()) {
- return tracker.get_next();
- }
- return null;
- }
- public virtual T last(owned PredicateDelegate<T>? predicate = null) throws SequenceError {
- var tracker = predicate == null ? get_tracker() : where((owned)predicate).get_tracker();
- if(!tracker.has_next()) {
- throw new SequenceError.NO_ELEMENTS("The sequence contains no elements");
- }
- while(true) {
- T item = tracker.get_next();
- if(!tracker.has_next()) {
- return item;
- }
- }
- }
- public virtual T? last_or_default(owned PredicateDelegate<T>? predicate = null) {
- var tracker = predicate == null ? get_tracker() : where((owned)predicate).get_tracker();
- if(!tracker.has_next()) {
- return null;
- }
- while(true) {
- T item = tracker.get_next();
- if(!tracker.has_next()) {
- return item;
- }
- }
- }
- public virtual T single(owned PredicateDelegate<T>? predicate = null) throws SequenceError {
- var tracker = predicate == null ? get_tracker() : where((owned)predicate).get_tracker();
- if(tracker.has_next()) {
- var item = tracker.get_next();
- if(tracker.has_next()) {
- throw new SequenceError.MULTUPLE_ELEMENTS("The sequence contains more than one element");
- }
- return item;
- }
- throw new SequenceError.NO_ELEMENTS("The sequence contains no elements");
- }
- public virtual T single_or_default(owned PredicateDelegate<T>? predicate = null) throws SequenceError {
- var tracker = predicate == null ? get_tracker() : where((owned)predicate).get_tracker();
- if(tracker.has_next()) {
- var item = tracker.get_next();
- if(tracker.has_next()) {
- throw new SequenceError.MULTUPLE_ELEMENTS("The sequence contains more than one element");
- }
- return item;
- }
- return null;
- }
- public virtual string to_string(TransformDelegate<T, string> stringifier, string seperator = "") {
- bool is_first = true;
- return aggregate<string>("", (s, v) => {
- if(is_first) {
- is_first = false;
- return stringifier(v);
- }
- return s + seperator + stringifier(v);
- });
- }
- public virtual Object[] to_object_array() throws SequenceError {
- if(!typeof(T).is_object()) {
- throw new SequenceError.INVALID_TYPE("Can only make an object array of an Enumerable<T> where T is derrived from GLib.Object");
- }
- return select<Object>(i => (Object)i).to_array();
- }
- public virtual Vector<T> to_vector() {
- var vector = new Vector<T>();
- vector.add_all(this);
- return vector;
- }
- public virtual Type element_type { get {
- return typeof(T);
- }}
- public virtual TPromotion promote_to<TPromotion>() throws PromotionError {
- var type = typeof(TPromotion);
- if(get_type().is_a(type)) {
- // Don't promote if we are already target type
- return this;
- }
- resolve_promotion<TPromotion>(ref type);
- if(!type.is_instantiatable()) {
- throw new PromotionError.INVALID_PROMOTION_TYPE(@"Promotion type $(type.name()) is not instansiatable.");
- }
- if(!type.is_a(typeof(Promotion))) {
- throw new PromotionError.INVALID_PROMOTION_TYPE(@"Promotion type $(type.name()) does not implement Invercargill.Promotion.");
- }
- if(!type.is_a(typeof(Enumerable)) && typeof(TPromotion) == type) {
- throw new PromotionError.INVALID_PROMOTION_TYPE(@"Non-resolved promotion type $(type.name()) does not inherit from Invercargill.Enumerable.");
- }
- var promotion = Object.new(type);
- if(!((Promotion)promotion).can_wrap(element_type)) {
- throw new PromotionError.INCOMPATIBLE_ELEMENT_TYPE(@"Enumerable has an element type of $(element_type.name()) which cannot be wrapped by $(type.name())");
- }
- return ((Promotion)promotion).wrap(this);
- }
- public virtual TPromotion assert_promotion<TPromotion>() {
- try {
- return promote_to<TPromotion>();
- }
- catch (PromotionError error) {
- var base_type = get_type();
- var type = typeof(TPromotion);
- critical(@"Cannot promote type $(base_type.name()) to $(type.name()): $(error.message)");
- assert_not_reached();
- }
- }
- public virtual Enumerable<T> seal() {
- if(this.get_type().is_a(typeof(Sealed))) {
- return this;
- }
- return new Sealed<T>(this);
- }
- public virtual Enumerable<T> cache() {
- if(this.get_type().is_a(typeof(Cache))) {
- return this;
- }
- return new Cache<T>(this);
- }
- public virtual Dictionary<TKey, T> to_dictionary<TKey>(TransformDelegate<T, TKey> key_selecter, HashDelegate<TKey>? key_hash_func = null, EqualityDelegate<TKey>? key_equal_func = null) {
- var dict = new Dictionary<TKey, T>(key_hash_func, key_equal_func);
- iterate(i => dict.add(key_selecter(i), i));
- return dict;
- }
- public virtual Dictionary<TKey, TValue> select_to_dictionary<TKey, TValue>(TransformDelegate<T, TKey> key_selecter, TransformDelegate<T, TValue> value_selecter, HashDelegate<TKey>? key_hash_func = null, EqualityDelegate<TKey>? key_equal_func = null) {
- var dict = new Dictionary<TKey, T>(key_hash_func, key_equal_func);
- iterate(i => dict.add(key_selecter(i), value_selecter(i)));
- return dict;
- }
- public virtual HashSet<T> to_hash_set(HashDelegate<T>? hash_func = null, EqualityDelegate<T>? equal_func = null) {
- var @set = new HashSet<T>(hash_func, equal_func);
- @set.union_with(this);
- return @set;
- }
- public virtual Enumerable<PositionItemPair<T>> with_positions() {
- return new Position<T>(this);
- }
- public virtual Elements to_elements() {
- var series = new ElementSeries();
- if(typeof(T).is_a(typeof(Element))) {
- series.add_all((Enumerable<Element>)this);
- }
- else {
- series.add_all(select<Element>(i => new NativeElement<T>(i)));
- }
- return series;
- }
- public virtual Attempts<Tout> attempt_map_with<Tout>(Mapper<Tout, T> mapper) {
- return attempt_select<Tout>(o => mapper.materialise(o));
- }
- public virtual Enumerable<T> as_enumerable() {
- return this;
- }
- private PredicateDelegate<T> resolve_nullable_predicate(PredicateDelegate<T>? predicate) {
- if(predicate == null) {
- return (p) => true;
- }
- return predicate;
- }
- }
- }
|