namespace Invercargill {

    private class CacheEnumerable<T> : Enumerable<T> {

        private Vector<T> vector;
        private Enumerable<T> inner;
        private Tracker<T> inner_tracker;

        public CacheEnumerable(Enumerable<T> inner) {
            this.inner = inner;
            inner_tracker = this.inner.get_tracker();
            vector = new Vector<T>();
        }

        public override Tracker<T> get_tracker () {
            var i = 0;
            return new LambdaTracker<T>(() => has_nth(i), () => vector.get_or_default(i++));
        }

        private bool has_nth(int n) {
            lock(vector) {
                if(vector.count() > n) {
                    return true;
                }
                while(vector.count() <= n) {
                    if(inner_tracker.has_next()) {
                        vector.add(inner_tracker.get_next());
                    }
                    else {
                        return false;
                    }
                }
                return true;
            }
        }

    }

}