namespace Invercargill.Modifiers {

    public class Filter<T> : Enumerable<T> {
        private PredicateDelegate<T> predicate_func;
        private Enumerable<T> input;

        public Filter(Enumerable<T> input, owned PredicateDelegate<T> func) {
            this.input = input;
            predicate_func = (owned)func;
        }

        public override uint? peek_count() {
            return null;
        }

        public override EnumerableInfo get_info() {
            return new EnumerableInfo.infer_single(this, EnumerableCategory.COMPUTED, input);
        }        

        public override Tracker<T> get_tracker() {
            var tracker = input.get_tracker();

            return new AdvanceTracker<T>((out obj) => {
                while(tracker.has_next()) {
                    var item = tracker.get_next();
                    if(predicate_func(item)){
                        obj = item;
                        return true;
                    }
                }
                obj = null;
                return false;
            });
        }
    }

}