Invercargill-Sql-Inversion/src/meson.build

sources = files(
    'DatabaseConfigurator.vala',
    'MigrationStartupService.vala',
    'InversionTypeProvider.vala'
)

dependencies = [
    glib_dep,
    gobject_dep,
    invercargill_dep,
    inversion_dep,
    invercargill_sql_dep
]

lib_sql_inversion = shared_library('invercargill-sql-inversion', sources,
    dependencies: dependencies,
    install: true,
    vala_gir: 'invercargill_sql_inversion-0.1.gir',
    install_dir: [true, true, true, true]
)

invercargill_sql_inversion_dep = declare_dependency(
    link_with: lib_sql_inversion,
    dependencies: dependencies
)

g_ir_compiler = find_program('g-ir-compiler')
custom_target('invercargill-sql-inversion typelib', command: [g_ir_compiler, '--shared-library=libinvercargill-sql-inversion-0.1.so', '--output', '@OUTPUT@', meson.current_build_dir() / 'invercargill_sql_inversion-0.1.gir'],
              output: 'invercargill-sql-inversion-0.1.typelib',
              depends: lib_sql_inversion,
              install: true,
              install_dir: get_option('libdir') / 'girepository-1.0')

# Generate pkg-config file
pkg = import('pkgconfig')
pkg.generate(lib_sql_inversion,
    version: meson.project_version(),
    name: 'invercargill-sql-inversion'
)