GtkCommonMark/src/lib/meson.build

vapi_dir = meson.current_source_dir() / 'vapi'

add_project_arguments(['--disable-warnings', '--enable-checking','--vapidir', vapi_dir], language: 'vala')

dependencies = [
    dependency('glib-2.0'),
    dependency('gobject-2.0'),
    dependency('gio-2.0'),
    dependency('gtk4'),
    meson.get_compiler('vala').find_library('libcmark', dirs: vapi_dir),
    meson.get_compiler('c').find_library('cmark'),
]

sources = files('Reader.vala')
sources += files('TagManager.vala')
sources += files('NodeActions/NodeAction.vala')
sources += files('NodeActions/Heading.vala')
sources += files('NodeActions/Emphisis.vala')
sources += files('NodeActions/Strong.vala')
sources += files('NodeActions/List.vala')
sources += files('NodeActions/Item.vala')

libgtkcmark = shared_library('gtkcommonmark', sources,
    dependencies: dependencies,
    install: true,
    vala_gir: 'GtkCommonMark-1.0.gir',
    install_dir: [true, true, true, true]
)
libgtkcmark_dep = declare_dependency(link_with: libgtkcmark, include_directories: include_directories('.'))

pkg = import('pkgconfig')
pkg.generate(libgtkcmark,
    version : '0.1',
    name : 'libgtkcommonmark',)
    
g_ir_compiler = find_program('g-ir-compiler')
custom_target('gtkcommonmark typelib', command: [g_ir_compiler, '--shared-library=libgtkcommonmark.so', '--output', '@OUTPUT@', meson.current_build_dir() / 'GtkCommonMark-1.0.gir'],
              output: 'GtkCommonMark-1.0.typelib',
              depends: libgtkcmark,
              install: true,
              install_dir: get_option('libdir') / 'girepository-1.0')